home *** CD-ROM | disk | FTP | other *** search
/ The X-Philes (2nd Revision) / The X-Philes Number 1 (1995).iso / xphiles / hp48hor1 / lll.src < prev    next >
Text File  |  1990-10-18  |  1KB  |  48 lines
  1. %%HP: T(3)A(D)F(.);
  2. @ Lincoln Labs Logo, a Lissajous animation.
  3. @ by Rob Steele
  4. DIR
  5.     GEN \<<
  6.         @ Generates a list of graphic objects and stores them in IMAGES.
  7.         @ Only run this once.  From then on, just run SHO.
  8.         RCLF DEG
  9.         0 'IMAGES' STO
  10.         30 90 FOR i
  11.             i 'Z' STO
  12.             ERASE DRAW PICT RCL
  13.         10 STEP @ (90-30)/10+1=7; change as required for other effects.
  14.         7 \->LIST 'IMAGES' STO
  15.         STOF
  16.         1250 1 BEEP
  17.     \>>
  18.  
  19.     SHO \<<
  20.         @ Displays the graphic objects in IMAGES in rapid succession.
  21.         IMAGES SIZE \-> n
  22.         \<<
  23.             ERASE { # 0h # 0h } PVIEW
  24.             MEM DROP
  25.             WHILE KEY NOT REPEAT
  26.                 1 n 1 - FOR i
  27.                     PICT {  # 0h # 0h } 'IMAGES' i GET REPL
  28.                 NEXT
  29.                 n 2 FOR i
  30.                     PICT {  # 0h # 0h } 'IMAGES' i GET REPL
  31.                 -1 STEP
  32.             END
  33.             DROP
  34.         \>>
  35.     \>>
  36.  
  37.     @ Definition of the lissajous.
  38.     @ Set Z to zero to produce the Lincoln logo.
  39.     EQ 'SIN(4*x+Z)+COS(3*x)*i'
  40.  
  41.     Z 0
  42.  
  43.     PPAR { (-3,-1) (3,1) { x 0 360 } 0 (10,10) PARAMETRIC Y }
  44.     @ change resolution for special effects.
  45.  
  46.     IMAGES 0
  47. END
  48.